cmake_minimum_required(VERSION 3.5)
set(PROJECT abb)
set(VERSION "1.0")
project(${PROJECT} LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 11)

set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTORCC ON)
set(CMAKE_AUTOUIC ON)
set(CMAKE_INCLUDE_CURRENT_DIR ON)

# Set the QT version
find_package(Qt6 COMPONENTS Core QUIET)
if (NOT Qt6_FOUND)
    set(QT_VERSION 5 CACHE STRING "Qt version for QGeoView")
else()
    set(QT_VERSION 6 CACHE STRING "Qt version for QGeoView")
endif()

find_package(Qt${QT_VERSION} REQUIRED COMPONENTS
    Core
    Gui
    Widgets
    Network
    Sql
    Xml
)

add_executable(${PROJECT}
    dbadapter.h
    dbadapter.cpp
    generic.h
    generic.cpp
    importer.h
    importer.cpp
    layerstored.h
    layerstored.cpp
    main.cpp
    mainwindow.h
    mainwindow.cpp
    node.h
    node.cpp
    nodemapper.h
    nodemapper.cpp
    viewzone.h
    viewzone.cpp

    resources.qrc
)

target_link_libraries(${PROJECT}
    PRIVATE
    Qt${QT_VERSION}::Core
    Qt${QT_VERSION}::Network
    Qt${QT_VERSION}::Gui
    Qt${QT_VERSION}::Widgets
    Qt${QT_VERSION}::Sql
    Qt${QT_VERSION}::Xml
    -lqgeoview
)
install(TARGETS ${PROJECT} DESTINATION ${CMAKE_INSTALL_BINDIR})

# Packages
set(CPACK_PACKAGE_NAME "${PROJECT}")
set(CPACK_PACKAGE_VERSION "${VERSION}")
set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Shows map with street cameras")
set(CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}.${CMAKE_SYSTEM_PROCESSOR}")

find_program(DPKG_PROGRAM dpkg)
find_program(RPMBUILD_PROGRAM rpmbuild)
if(DPKG_PROGRAM AND NOT CPACK_GENERATOR)
    set(CPACK_GENERATOR "DEB")
elseif(RPMBUILD_PROGRAM AND NOT CPACK_GENERATOR)
    # If QGeoView is not managed by RPM created package will have broken dependency. Exclude this lib
    set(CPACK_RPM_SPEC_MORE_DEFINE "%define __requires_exclude ^(libqgeoview\\.so.*)$")
    set(CPACK_GENERATOR "RPM")
endif()

include(CPack)
